Excel用公式進(jìn)行多條件求和

　　需要用excel統(tǒng)計(jì)數(shù)據(jù)的時(shí)候，多條件求和在實(shí)際的工作中應(yīng)用非常廣泛，我們可以用公式來實(shí)現(xiàn)多條件求和，用到的函數(shù)有SUM、SUMPRODUCT、MMULT和SUMIFS，其中SUMIFS函數(shù)是Excel2007新增的函數(shù)。下面是小編整理的Excel用公式進(jìn)行多條件求和，希望能夠幫助到大家。

　　方法一：用SUM函數(shù)

　　用SUM函數(shù)進(jìn)行多條件求和，公式基本結(jié)構(gòu)是SUM((條件1)*(條件2)*(求和數(shù)據(jù)區(qū)))，

　　必需用數(shù)組公式，公式輸入完畢后按Ctrl+Alt+Enter結(jié)束。

　　1.計(jì)算出7月份廣州的總銷量：

　　=SUM(($A$2:$A$23="7月")*($B$2:$B$23="廣州")*$F$2:$F$23)

　　2.計(jì)算出7月和10月拖鞋總銷量：

　　=SUM((($A$2:$A$23="7月")+($A$2:$A$23="10月"))*($C$2:$C$23="拖鞋")*$F$2:$F$23)

　　公式中的加號(hào)相當(dāng)于邏輯或。

　　3.計(jì)算出7-10月武漢男式襪子銷量：

　　=SUM((($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))*($E$2:$E$23="男")*$F$2:$F$23)

　　方法二：用SUMPRODUCT函數(shù)

　　公式結(jié)構(gòu)同SUM函數(shù)，只不過不用數(shù)組公式。

　　1.計(jì)算出7月份廣州的總銷量：

　　=SUMPRODUCT(($A$2:$A$23="7月")*($B$2:$B$23="廣州")*$F$2:$F$23)

　　2.計(jì)算出7月和10月拖鞋總銷量：

　　=SUMPRODUCT((($A$2:$A$23="7月")+($A$2:$A$23="10月"))*($C$2:$C$23="拖鞋")*$F$2:$F$23)

　　公式中的加號(hào)相當(dāng)于邏輯或。

　　3.計(jì)算出7-10月武漢男式襪子銷量：

　　=SUMPRODUCT((($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))*($E$2:$E$23="男")*$F$2:$F$23)

　　方法三：用MMULT函數(shù)

　　用MMULT函數(shù)進(jìn)行多條件求和特別適合于數(shù)據(jù)量較大的情況。

　　MMULT函數(shù)的語(yǔ)法是：MMULT(array1,array2)，

　　其中參數(shù)array1和array2 是要進(jìn)行矩陣乘法運(yùn)算的兩個(gè)數(shù)組。

　　函數(shù)返回兩個(gè)數(shù)組的矩陣乘積。要求array1 的列數(shù)必須與 array2 的行數(shù)相同，

　　而且兩個(gè)數(shù)組中都只能包含數(shù)值。本例中的第一參數(shù)為一行N列，而第二參數(shù)為N行一列。

　　公式的基本結(jié)構(gòu)是MMULT(條件1，(條件2)*(求和數(shù)據(jù)區(qū)))，

　　必需用數(shù)組公式，公式輸入完畢后按Ctrl+Alt+Enter結(jié)束。

　　1.計(jì)算出7月份廣州的總銷量：

　　=MMULT(--(TRANSPOSE($A$2:$A$23)="7月"),($B$2:$B$23="廣州")*$F$2:$F$23)

　　公式中雙重否定符“--”將其后面的結(jié)果變成數(shù)值。

　　2.計(jì)算出7月和10月拖鞋總銷量：

　　=MMULT(--(TRANSPOSE(($A$2:$A$23="7月")+($A$2:$A$23="10月"))),($C$2:$C$23="拖鞋")*$F$2:$F$23)

　　公式中的加號(hào)相當(dāng)于邏輯或。

　　3.計(jì)算出7-10月武漢男式襪子銷量：

　　=MMULT(--(TRANSPOSE(($B$2:$B$23="武漢")*($C$2:$C$23="襪子"))),($E$2:$E$23="男")*$F$2:$F$23)

　　方法四：用SUMIFS函數(shù)

　　SUMIFS函數(shù)是Excel 2007中的新增函數(shù)，用它進(jìn)行多條件求和非常方便。其語(yǔ)法是：

　　SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], …),即：

　　SUMIFS(求和區(qū)域,條件區(qū)域1，條件1，[條件區(qū)域2，條件2]，…)

　　1.計(jì)算出7月份廣州的總銷量：

　　=SUMIFS($F$2:$F$23,$A$2:$A$23,"7月",$B$2:$B$23,"廣州")

　　2.計(jì)算出7月和10月拖鞋總銷量：

　　=SUMIFS($F$2:$F$23,$A$2:$A$23,"7月",$C$2:$C$23,"拖鞋")+SUMIFS($F$2:$F$23,$A$2:$A$23,"10月",$C$2:$C$23,"拖鞋")

　　3.計(jì)算出7-10月武漢男式襪子銷量：

　　=SUMIFS($F$2:$F$23,$B$2:$B$23,"武漢",$C$2:$C$23,"襪子",$E$2:$E$23,"男")

　　拓展：常用的Excel函數(shù)公式大全

　　一、數(shù)字處理

　　1、取絕對(duì)值

　　=ABS(數(shù)字)

　　2、取整

　　=INT(數(shù)字)

　　3、四舍五入

　　=ROUND(數(shù)字,小數(shù)位數(shù))

　　二、判斷公式

　　1、把公式產(chǎn)生的錯(cuò)誤值顯示為空

　　公式：C2

　　=IFERROR(A2/B2,"")

　　說明：如果是錯(cuò)誤值則顯示為空，否則正常顯示。

　　2、IF多條件判斷返回值

　　公式：C2

　　=IF(AND(A2<500,B2="未到期"),"補(bǔ)款","")

　　說明：兩個(gè)條件同時(shí)成立用AND,任一個(gè)成立用OR函數(shù)。

　　三、統(tǒng)計(jì)公式

　　1、統(tǒng)計(jì)兩個(gè)表格重復(fù)的內(nèi)容

　　公式:B2

　　=COUNTIF(Sheet15!A:A,A2)

　　說明：如果返回值大于0說明在另一個(gè)表中存在，0則不存在。

　　2、統(tǒng)計(jì)不重復(fù)的總?cè)藬?shù)

　　公式：C2

　　=SUMPRODUCT(1/COUNTIF(A2:A8,A2:A8))

　　說明:用COUNTIF統(tǒng)計(jì)出每人的出現(xiàn)次數(shù)，用1除的方式把出現(xiàn)次數(shù)變成分母，然后相加。

【Excel用公式進(jìn)行多條件求和】相關(guān)文章：

excel表格怎么求和08-16

如何在excel自動(dòng)求和07-18

EXCEL公式與函數(shù)教案12-13

excel表格公式大全06-17

excel公式如何解讀07-21

最常用的Excel函數(shù)公式匯總09-11

Excel表格乘法函數(shù)公式大全10-24

excel公式錯(cuò)誤返回值05-25

在Excel中遇到錯(cuò)誤“#DIV/0!”的公式12-09

EXCEL有哪些條件功能09-18